Calendrier - Mise en forme conditionnelle

[Jero]

Bonjour à tous,
Je suis désolé, mon précédent message se retrouve ds le fil d'une discussion
qui avait le même objet que le mien... (Mise en forme conditionnelle posté
par Alphomega(J-L M.) du 27/08/2004
Voilà donc ce qui m'amène...

J'ai créé un calendrier "basique" :

Colonne A,B et C : mois de Janvier

Colonne A : les jours (1/1/04, etc.) format jjj jj

Colonne B : Matin (cellules vides)

Colonne C : Après-midi (cellules vides)

Colonnes D,E et F : mois de février

Même "format" que pour Janvier

Etc.

Je souhaite (en utilisant Mise en forme conditionnelle) mettre en fond grisé
les week end (jour, matin et après-midi) avec une seule formule pour tous
les mois.



J'ai donc (après sélection de toute la plage) compléter la boîte de dialogue
Mise en forme cond. de la façon suivante :

La formule est

=OU(JOURSEM(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3)))=1;JOURSEM(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3)))=7)

.(première cellule en A3)

.et ça ne fonctionne pas alors que j'ai testé cette formule ds d'autres
cellules et elle renvoie bien VRAI ou FAUX.



Une idée ?

Rem : Excel 2003

D'avance merci, (rem : bon week-end prolongé...)

Jero

[AV]

Si tu souhaites, comme je le comprends, formater les plages dates en une seule
fois :
Sélection A3:AH33

MFC

=ET(MOD(COLONNE();3)=1;JOURSEM(A3;2)>=6)

AV

[Jero]

Salut AV et merci,
Mais, les colonnes "Matin" et "Après-midi" ne bénéficient pas de la MFC...
(et c'est là tout mon problème)
Voilà le tableau....
A B C D
E F G H
I J K L
Janvier Février
Matin Après-midi Matin Après-midi
jeu 01 dim 01 FAUX FAUX FAUX VRAI VRAI VRAI
ven 02 lun 02 FAUX FAUX FAUX FAUX FAUX FAUX
sam 03 mar 03 VRAI VRAI VRAI FAUX FAUX FAUX
dim 04 mer 04 VRAI VRAI VRAI FAUX FAUX FAUX
lun 05 jeu 05 FAUX FAUX FAUX FAUX FAUX FAUX
mar 06 ven 06 FAUX FAUX FAUX FAUX FAUX FAUX
mer 07 sam 07 FAUX FAUX FAUX VRAI VRAI VRAI
jeu 08 dim 08 FAUX FAUX FAUX VRAI VRAI VRAI


Ma formule de MFC sur la plage A3:F10 (extrait) est la suivante :
=OU(JOURSEM(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3)))=1;JOURSEM(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3)))=7)
Cette formule, je l'ai recopiée à partir de G3 ; elle renvoie bien VRAI ou
FAUX...
Alorssss, pourquoi, la MFC ne "fonctionne" pas... (des limites Excel ?)
Merci à tous
jero

Post by AV
Si tu souhaites, comme je le comprends, formater les plages dates en une seule
Sélection A3:AH33

MFC

=ET(MOD(COLONNE();3)=1;JOURSEM(A3;2)>=6)
AV

[AV]

Post by Jero
Mais, les colonnes "Matin" et "Après-midi" ne bénéficient pas de la MFC...

Sélection A3:AH33
--> MFC --> la formule est -->
=JOURSEM(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3));2)>=6
--> motif ...

AV

[AV]

Suite...
Pour être plus précis et éviter ainsi le formatage des cellules correspondant à
des dates non renseignées dans le tableau (mois de février et mois de 30 jours)
:

=(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3))<>"")*(JOURSEM(DECALER(A3;0;-MOD
(COLONNE(A3)-COLONNE($A3);3));2)>=6)

PS : pour XL une cellule vide correspond à la date équivalente au N° de série 0
c'est à dire 00/01/00 ou encore samedi 00 Janvier 1900 !!
AV

[Jero]

Re-salut AV,

Post by AV
PS : pour XL une cellule vide correspond à la date équivalente au N° de série 0
c'est à dire 00/01/00 ou encore samedi 00 Janvier 1900 !!

Oui, je sais...
Maintenant, ça roule... merci.
Joli cas d'école, n'est-il pas ? ;>)
En fait, je suis entrain d'écrire un petit topo sur la MFC en graduant les
difficultés... et voilà...
Si j'ai d'autres idées...
Encore merci,
jero

Post by AV
Suite...
Pour être plus précis et éviter ainsi le formatage des cellules correspondant à
des dates non renseignées dans le tableau (mois de février et mois de 30 jours)
=(DECALER(A3;0;-MOD(COLONNE(A3)-COLONNE($A3);3))<>"")*(JOURSEM(DECALER(A3;0;-MOD
(COLONNE(A3)-COLONNE($A3);3));2)>=6)
PS : pour XL une cellule vide correspond à la date équivalente au N° de série 0
c'est à dire 00/01/00 ou encore samedi 00 Janvier 1900 !!
AV

[AV]

Post by Jero
Joli cas d'école, n'est-il pas ? ;>)

Effectivement !
Au passage on ne peut que, une fois de plus, regretter que la MFC n'accepte pas
de formulation matricielle (XL2000)
Dans ce cas de figure, on aurait pu ainsi varier les plaisirs :

=(DECALER(A3;;INDEX({0;-1;-2};EQUIV(MOD(COLONNE();3);{1;2;0};0)))<>"")*(JOURSEM(
DECALER(A3;;INDEX({0;-1;-2};EQUIV(MOD(COLONNE();3);{1;2;0};0)));2)>=6)

Post by Jero
En fait, je suis entrain d'écrire un petit topo sur la MFC en graduant les
difficultés... et voilà...
Si j'ai d'autres idées...

Heu... je me permets de te signaler celles(idées) présentes là :
http://www.excelabo.net/moteurs/compteclic.php?nom=av-mefc

AV

[Starwing]

Bonjour Jero,

Ça va probablement beaucoup t'aider...
C'est un classeur justement de AV

http://www.excelabo.net/xl/formats.php#mefcdemo

Starwing

[Jero]

Merci,
Je ne suis pas sûr de retrouver dans le classeur en question la réponse à ma
question... (du moins celle que je me posais...)
....
Jero

Post by Starwing
Bonjour Jero,
Ça va probablement beaucoup t'aider...
C'est un classeur justement de AV
http://www.excelabo.net/xl/formats.php#mefcdemo
Starwing